捐赠 | 广告 | 注册 | 发布 | 上传 | 关于我们    
  沪ICP备05001939号 DELPHI盒子 | 盒子论坛 | 盒子文章 | 盒子问答悬赏 | 最新更新 | 论坛检索 | 下载中心 | 高级搜索    
  精品专区 | 繁體中文 | 奖励公告栏 | 直通车账号登陆 | 关闭GOOGLE广告 | 临时留言    
 
广告
评论:ZnCRC 数据校验
linda0606 24919 2006/7/14 14:53:44
我在使用中发现zncrc计算出来的CRC,有时不正确。这是怎么回事啊!
iamdream 24855 2006/7/10 21:35:12
可能是CRC32快一些吧,不过没测过^o^
register 24853 2006/7/10 17:26:17
CRC32 与 CRC16 哪个更快一点?
guanbo 24833 2006/7/9 7:50:15
学习ING....
MARK~!
iamdream 24832 2006/7/8 23:06:27
我看了下,作者发布的代码也是分块计算的;诚如coffeemay所说,CRC似乎没办法用多线程来计算,所以用Application.ProcessMessages就可以了
iamdream 24831 2006/7/8 22:52:38
以下是窗体代码(保存为Unit1.dfm : Delphi6):
object Form1: TForm1
  Left = 203
  Top = 105
  BorderIcons = [biSystemMenu]
  BorderStyle = bsSingle
  Caption = #35745#31639#25991#20214#30340'CRC32'#26657#39564#20540
  ClientHeight = 93
  ClientWidth = 378
  Color = clBtnFace
  Font.Charset = GB2312_CHARSET
  Font.Color = clWindowText
  Font.Height = -12
  Font.Name = #23435#20307
  Font.Style = []
  OldCreateOrder = False
  OnCreate = FormCreate
  PixelsPerInch = 96
  TextHeight = 12
  object lblCRC32: TLabel
    Left = 192
    Top = 60
    Width = 78
    Height = 12
    Alignment = taRightJustify
    Caption = '&CRC32'#26657#39564#20540#65306
    FocusControl = edtCRC32
  end
  object btnFile: TButton
    Left = 8
    Top = 7
    Width = 75
    Height = 25
    Caption = #25991#20214#21517'(&F)'
    TabOrder = 0
    OnClick = btnFileClick
  end
  object edtFile: TEdit
    Left = 83
    Top = 10
    Width = 286
    Height = 19
    BevelKind = bkSoft
    BorderStyle = bsNone
    TabOrder = 1
    Text = 'edtFile'
  end
  object btnCalcCRC32: TButton
    Left = 8
    Top = 54
    Width = 169
    Height = 25
    Caption = #35745#31639'CRC32'#26657#39564#20540'(&R)'
    TabOrder = 2
    OnClick = btnCalcCRC32Click
  end
  object edtCRC32: TEdit
    Left = 272
    Top = 56
    Width = 97
    Height = 19
    BevelKind = bkTile
    BorderStyle = bsNone
    TabOrder = 3
    Text = 'edtCRC32'
  end
  object OpenDialog1: TOpenDialog
    Filter = #20219#24847#25991#20214'(*.*)|*.*'
    Options = [ofHideReadOnly, ofFileMustExist, ofEnableSizing]
    Left = 112
    Top = 24
  end
end
iamdream 24830 2006/7/8 22:46:32
可以分块计算CRC的,以下是我的CRC32测试代码,其计算结果与WinRar/WinZip一致:
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    lblCRC32: TLabel;
    btnFile: TButton;
    edtFile: TEdit;
    btnCalcCRC32: TButton;
    edtCRC32: TEdit;
    OpenDialog1: TOpenDialog;
    procedure FormCreate(Sender: TObject);
    procedure btnFileClick(Sender: TObject);
    procedure btnCalcCRC32Click(Sender: TObject);
  private
    { Private declarations }
    m_bExit: Boolean;    //校验过程中用户选“退出”???
    m_bCalcing: Boolean; //正在校验???
    function CalcCrc32OfFile(const sFileName: string): DWORD;
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

var
  crc32table: array[0..255] of DWORD =
(
 $00000000, $77073096, $EE0E612C, $990951BA,
 $076DC419, $706AF48F, $E963A535, $9E6495A3,
 $0EDB8832, $79DCB8A4, $E0D5E91E, $97D2D988,
 $09B64C2B, $7EB17CBD, $E7B82D07, $90BF1D91,
 $1DB71064, $6AB020F2, $F3B97148, $84BE41DE,
 $1ADAD47D, $6DDDE4EB, $F4D4B551, $83D385C7,
 $136C9856, $646BA8C0, $FD62F97A, $8A65C9EC,
 $14015C4F, $63066CD9, $FA0F3D63, $8D080DF5,
 $3B6E20C8, $4C69105E, $D56041E4, $A2677172,
 $3C03E4D1, $4B04D447, $D20D85FD, $A50AB56B,
 $35B5A8FA, $42B2986C, $DBBBC9D6, $ACBCF940,
 $32D86CE3, $45DF5C75, $DCD60DCF, $ABD13D59,
 $26D930AC, $51DE003A, $C8D75180, $BFD06116,
 $21B4F4B5, $56B3C423, $CFBA9599, $B8BDA50F,
 $2802B89E, $5F058808, $C60CD9B2, $B10BE924,
 $2F6F7C87, $58684C11, $C1611DAB, $B6662D3D,

 $76DC4190, $01DB7106, $98D220BC, $EFD5102A,
 $71B18589, $06B6B51F, $9FBFE4A5, $E8B8D433,
 $7807C9A2, $0F00F934, $9609A88E, $E10E9818,
 $7F6A0DBB, $086D3D2D, $91646C97, $E6635C01,
 $6B6B51F4, $1C6C6162, $856530D8, $F262004E,
 $6C0695ED, $1B01A57B, $8208F4C1, $F50FC457,
 $65B0D9C6, $12B7E950, $8BBEB8EA, $FCB9887C,
 $62DD1DDF, $15DA2D49, $8CD37CF3, $FBD44C65,
 $4DB26158, $3AB551CE, $A3BC0074, $D4BB30E2,
 $4ADFA541, $3DD895D7, $A4D1C46D, $D3D6F4FB,
 $4369E96A, $346ED9FC, $AD678846, $DA60B8D0,
 $44042D73, $33031DE5, $AA0A4C5F, $DD0D7CC9,
 $5005713C, $270241AA, $BE0B1010, $C90C2086,
 $5768B525, $206F85B3, $B966D409, $CE61E49F,
 $5EDEF90E, $29D9C998, $B0D09822, $C7D7A8B4,
 $59B33D17, $2EB40D81, $B7BD5C3B, $C0BA6CAD,

 $EDB88320, $9ABFB3B6, $03B6E20C, $74B1D29A,
 $EAD54739, $9DD277AF, $04DB2615, $73DC1683,
 $E3630B12, $94643B84, $0D6D6A3E, $7A6A5AA8,
 $E40ECF0B, $9309FF9D, $0A00AE27, $7D079EB1,
 $F00F9344, $8708A3D2, $1E01F268, $6906C2FE,
 $F762575D, $806567CB, $196C3671, $6E6B06E7,
 $FED41B76, $89D32BE0, $10DA7A5A, $67DD4ACC,
 $F9B9DF6F, $8EBEEFF9, $17B7BE43, $60B08ED5,
 $D6D6A3E8, $A1D1937E, $38D8C2C4, $4FDFF252,
 $D1BB67F1, $A6BC5767, $3FB506DD, $48B2364B,
 $D80D2BDA, $AF0A1B4C, $36034AF6, $41047A60,
 $DF60EFC3, $A867DF55, $316E8EEF, $4669BE79,
 $CB61B38C, $BC66831A, $256FD2A0, $5268E236,
 $CC0C7795, $BB0B4703, $220216B9, $5505262F,
 $C5BA3BBE, $B2BD0B28, $2BB45A92, $5CB36A04,
 $C2D7FFA7, $B5D0CF31, $2CD99E8B, $5BDEAE1D,

 $9B64C2B0, $EC63F226, $756AA39C, $026D930A,
 $9C0906A9, $EB0E363F, $72076785, $05005713,
 $95BF4A82, $E2B87A14, $7BB12BAE, $0CB61B38,
 $92D28E9B, $E5D5BE0D, $7CDCEFB7, $0BDBDF21,
 $86D3D2D4, $F1D4E242, $68DDB3F8, $1FDA836E,
 $81BE16CD, $F6B9265B, $6FB077E1, $18B74777,
 $88085AE6, $FF0F6A70, $66063BCA, $11010B5C,
 $8F659EFF, $F862AE69, $616BFFD3, $166CCF45,
 $A00AE278, $D70DD2EE, $4E048354, $3903B3C2,
 $A7672661, $D06016F7, $4969474D, $3E6E77DB,
 $AED16A4A, $D9D65ADC, $40DF0B66, $37D83BF0,
 $A9BCAE53, $DEBB9EC5, $47B2CF7F, $30B5FFE9,
 $BDBDF21C, $CABAC28A, $53B39330, $24B4A3A6,
 $BAD03605, $CDD70693, $54DE5729, $23D967BF,
 $B3667A2E, $C4614AB8, $5D681B02, $2A6F2B94,
 $B40BBE37, $C30C8EA1, $5A05DF1B, $2D02EF8D
);

procedure InitCrc32Table;
var
  bOk: Boolean;
  i, j: Integer;
  dwCrc: DWORD;
begin
  for i := 0 to 255 do
  begin
     dwCrc := i;  //必须为DWORD !!!!否则得不到正确的CRC32表
     for j := 0 to 7 do
     begin
         bOk   := Boolean(dwCrc and 1);
         dwCrc := dwCrc shr 1;
         if bOk then
          dwCrc := dwCrc xor $EDB88320;
     end;
     crc32table[i] := dwCrc;
  end;
end;

function Crc32(Buf: PChar; Length: DWORD): DWORD;
var          //一次计算CRC32值
  crc, i, dwTemp: DWORD;
begin
  crc := $FFFFFFFF;
  for i := 0 to Length -1 do
  begin
     dwTemp := (crc xor Byte(Buf^)) and $000000FF;
     Inc(Buf);
     crc := ( crc shr 8) xor crc32table[dwTemp];
  end;
  Result := not crc;
  {
      //以下为不用表的算法!!!经过检验的!!! 2003.2.20.
      /* crc polynomial for Ethernet */
      //const unsigned long poly = 0xedb88320;
      /* crc value - preinitialized to all 1's */
      /*unsigned long crc_value = 0xffffffff;

      for (unsigned int perByte = 0; perByte < length; perByte ++ )
        begin
       unsigned char c = *(s++);
       for (int perBit = 0; perBit < 8; perBit++ )
          begin
        crc_value = (crc_value>>1)^
         (((crc_value^c)&0x01)?poly:0);
        c >>= 1;
       end;
      end;
      return ~crc_value;*/
  }
end;

function CalcCRC32(dwCrc32: DWORD; Buf: PChar; dwLen: DWORD): DWORD;
var          //分块计算CRC32校验值(每次计算一小块)
  i, dwTemp: DWORD;          //查看算比不用表直接算速度要快得多 2005.8.28
begin
  for i := 0 to dwLen -1 do
  begin
    dwTemp  := (dwCrc32 xor Byte(Buf^)) and $000000FF;
    Inc(Buf);
    dwCrc32 := (dwCrc32 shr 8) xor crc32table[dwTemp];
  end;
  Result := dwCrc32;
end;

function CalcCRC32Direct(dwCrc32: DWORD; Buf: PChar; dwLen: DWORD): DWORD;
const          //分块计算CRC32校验值(每次计算一小块)
  dwPoly: DWORD = $EDB88320; //<不用表直接算,经过检验的 2005.8.28>
var
  bXor: Boolean;
  i, j: DWORD;
  btNow: Byte;
begin
  for i := 0 to dwLen - 1 do //按字节算
  begin
    btNow := Byte(Buf^);
    for j := 0 to 7 do       //按位算
    begin
      bXor := ((dwCrc32 xor btNow)and $1) <> 0;
      dwCrc32 := dwCrc32 shr 1;
      if bXor then
        dwCrc32 := dwCrc32 xor dwPoly;
      btNow := btNow shr 1;
    end;
    Inc(Buf);
  end;
  Result := dwCrc32;
end;


procedure TForm1.FormCreate(Sender: TObject);
begin
  Application.Title := Caption;
end;

function TForm1.CalcCrc32OfFile(const sFileName: string): DWORD;
const          //分块计算CRC32校验值
  BlockSize = 4096;      //每次计算一小块
var
  pCache, pp: PChar;
  dwCrc: DWORD;
  iPos: int64;
  iLen: Integer;
  sInfo: String;
begin
  Result := 0;
  if FileExists(sFileName) then
  begin
    with TFileStream.Create(sFileName, fmOpenRead) do
      try
        GetMem(pCache, BlockSize);
        try
          pp    := pCache;
          dwCrc := $FFFFFFFF;
          iPos  := 0;
          while iPos < Size do  //本循环计算CRC32校验值
          begin
          sInfo := Format('%d%%', [Trunc(iPos*100.0 / Size)]);
          if sInfo <> edtCRC32.Text then   //计算大文件时减少刷新
          edtCRC32.Text := sInfo;
          iLen := Read(pCache^, BlockSize);
          if iLen > 0 then
          dwCrc := CalcCRC32{Direct}(dwCrc, pp, iLen);
          Inc(iPos, BlockSize);
          Application.ProcessMessages();
          if m_bExit then          //退出
          break;
          end;
          Result := not dwCrc;         //取一下反,使得其值与WinZip,WinRAR一致
        finally
          FreeMem(pCache, BlockSize);
        end;
      finally
        Free;
      end;
  end;
end;

procedure TForm1.btnFileClick(Sender: TObject);
begin
  if OpenDialog1.Execute then
    edtFile.Text := OpenDialog1.FileName;
end;

procedure TForm1.btnCalcCRC32Click(Sender: TObject);
var
  sCap: string;
begin
  Screen.Cursor    := crHourGlass;
  sCap          := lblCRC32.Caption;
  lblCRC32.Caption := '校验进度:';
  m_bCalcing       := true;
  edtCRC32.Text    := '$' + IntToHex(integer(CalcCRC32OfFile(edtFile.Text)), 8);
  m_bCalcing       := false;
  lblCRC32.Caption := sCap;
  Screen.Cursor    := crDefault;
end;

end.
coffeemay 24829 2006/7/8 20:43:33
good!代码很工整,看起来很舒服
不过虽然用到了TThread似乎依然是单线程的,慢是CRC天生的缺陷,好像没办法用多线程实现(因为它的下一个数值必须依赖上一个)【如果分段倒是可以用多线程,但是就不是真正的CRC算法了,可靠度降低了】。
第一页 上一页 下一页 最后页 有 8 条纪录 共1页 1 - 8
 用户名:
 密 码:
自动登陆(30天有效)
 
  DELPHI盒子版权所有 1999-2012 V3.01 沪ICP备05001939号 更新RSS列表